Безопасность Grails REST — добавление идентификатора пользователя в токен

avatar
ziftech
8 апреля 2018 в 07:53
1328
2
2

Я хочу добавить поле идентификатора пользователя в токен, возвращаемый из /api/login

Сейчас это:

{
    "username": "user",
    "roles": [
        "ROLE_USER"
    ],
    "token_type": "Bearer",
    "access_token": "eyJhbGciOiJIUzI1NiJ9.2uk2YoHsyd7bqUdtUYN19ef..",
    "expires_in": 3600,
    "refresh_token": "eyJhbGciOiJIUzI1NiJ9.eyJwcmluY2lwYWwiOiJINH.."
}

Мне нужно:

{
    "id": "1",
    "username": "user",
    "roles": [
        "ROLE_USER"
    ],
    "token_type": "Bearer",
    "access_token": "eyJhbGciOiJIUzI1NiJ9.2uk2YoHsyd7bqUdtUYN19ef..",
    "expires_in": 3600,
    "refresh_token": "eyJhbGciOiJIUzI1NiJ9.eyJwcmluY2lwYWwiOiJINH.."
}

цель - запросы с идентификатором пользователя, например POST /api/something Есть ли другие подходы? Заранее спасибо

Источник

Ответы (2)

avatar
Prakash Thete
17 апреля 2018 в 06:58
10

Вы не упомянули версию Grails, поэтому я публикую ответ, который реализовал для Grails 2.4.4

Первое, что вам нужно для реализации интерфейса AccessTokenJsonRenderer в вашем пользовательском классе, созданном в src/groovy, как показано ниже.

import grails.plugin.springsecurity.SpringSecurityUtils
import grails.plugin.springsecurity.rest.token.AccessToken
import grails.plugin.springsecurity.rest.token.rendering.AccessTokenJsonRenderer
import groovy.json.JsonBuilder
import org.springframework.beans.factory.annotation.Autowired
import org.springframework.security.core.GrantedAuthority

/**
 * Created by Prakash Thete on 17/04/2018
 */
class CustomAppRestAuthTokenJsonRenderer implements AccessTokenJsonRenderer  {

    @Override
    String generateJson(AccessToken accessToken){

        // Add extra custom parameters if you want in this map to be rendered in login response
        Map response = [
                id           : accessToken.principal.id,
                username     : accessToken.principal.username,
                access_token : accessToken.accessToken,
                token_type   : "Bearer",
                refresh_token: accessToken.refreshToken,
                roles        : accessToken.authorities.collect { GrantedAuthority role -> role.authority }
        ]

        return new JsonBuilder( response ).toPrettyString()
    }
}

Второе, что вам нужно, чтобы создать bean-компонент нашего пользовательского класса в resources.groovy, как показано ниже

// For overriding the token json renderer
accessTokenJsonRenderer(CustomAppRestAuthTokenJsonRenderer)

Теперь после нажатия api/login вы получите идентификатор пользователя вместе с другими данными.

Надеюсь, это поможет!

avatar
Pila
7 апреля 2019 в 07:00
0

Если вы хотите добавить дополнительные сведения о пользователе в свой ответ Auth JSON, вы можете использовать основной идентификатор и запросить пользователя следующим образом.

Обратите внимание на добавление аннотации @Transactional.

import grails.gorm.transactions.Transactional
import grails.plugin.springsecurity.rest.token.AccessToken
import grails.plugin.springsecurity.rest.token.rendering.AccessTokenJsonRenderer
import groovy.json.JsonBuilder
import org.springframework.security.core.GrantedAuthority


@Transactional
class CustomAuthTokenRenderer implements AccessTokenJsonRenderer {


    @Override
    String generateJson(AccessToken accessToken) {

        // User the principal ID to get an instance of the user from the database
        User user = User.get accessToken.principal.id as Long

        // Add extra custom parameters if you want in this map to be rendered in login response

        Map res = [
                id               : user.id,
                username         : user.username,
                firstName        : user.firstName,
                lastName         : user.lastName,
                profilePicture   : user.profilePicture,
                dateOfBirth      : user.dob,
                expiration       : accessToken.expiration,
                access_token     : accessToken.accessToken,
                token_type       : "Bearer",
                refresh_token    : accessToken.refreshToken,
                roles            : accessToken.authorities.collect { GrantedAuthority role -> role.authority },
                friends: user.friends.collect { Friend friend ->
                    [
                            id          : friend.id,
                            firstName   : friend.firstName,
                            dateCreated : friend.dateCreated,
                            lastUpdated : friend.lastUpdated,
                    ]
                }
        ]

        return new JsonBuilder(res).toPrettyString()
    }
}

Неважно, что вы хотите добавить к ответу, с помощью пользовательского объекта вы можете добавить практически все что угодно. Просто не поддавайтесь искушению делать слишком много запросов, так как это приведет к очень медленному процессу входа в систему.